VBA Excelファイルをきれいに整えるマクロ

Sub excel_layout_fixup()

   '#画面更新オフ
   Application.ScreenUpdating = False

   '########## 変数定義 ##########
   '#現在のフォルダ
   Dim mydir As String
   
   '#対象のエクセルファイル
   Dim file As String
   
   '#各シート
   Dim s As Object
   
   '#インプットボックス
   Dim buf As String
   
   '#開始メッセージ
   Dim msg1 As String
   
   '#終了メッセージ
   Dim msg2 As String

 '########## 事前準備 ##########
   '#現在のフォルダを取得
   mydir = ThisWorkbook.Path & "/"
   
   '#フォルダ内エクセルを取得(最初のファイル名を取得)
   file = Dir(mydir & "*.xls*")
   
   '#開始メッセージ設定
   msg1 = "表示倍率を設定してください。" & vbCrLf & _
         "（デフォルトは100%です）"
      
   '#インプットボックスの設定
   buf = InputBox(msg1, Default:=100)

   '#終了メッセージ設定
   msg2 = "以下のファイルを修正保存しました。" & vbCrLf & "<A1セル選択、表示率" & buf & "%、スクロール最上位、最左側シート選択>" & vbCrLf & vbCrLf

 '########## メイン処理 ##########
   '#フォルダ配下のエクセルをすべて処理
   Do While file <> ""
     
     '#xls/xlsxをオープン ※xlsmファイルは除く
     'If LCase(file) Like "*.xls" And Not (LCase(file) Like "*.xlsm") Then
     If LCase(file) Like "*.xls" Or LCase(file) Like "*.xlsx" And Not (LCase(file) Like "*.xlsm") Then
     
       '#ファイルを開く
       Workbooks.Open Filename:=mydir & file
      
       '#各シートごと処理
       For Each s In ActiveWorkbook.Sheets

          '#シートをアクティブ
          s.Activate
          
          '#A1にカーソルを合わせる
          ActiveSheet.Range("A1").Select
       
          '#倍率を指定倍率にする※デフォルト100%
          ActiveWindow.Zoom = buf
         
          '#スクロールで一番左上へ
          ActiveWindow.ScrollColumn = 1
          ActiveWindow.ScrollRow = 1
   
       '#次のシートに対して処理する
       Next s
      
       '#一番左のシートに移動
       Sheets(1).Select
       
       '#上書き保存して閉じる
       ActiveWorkbook.Save
       ActiveWorkbook.Close
      
       '#終了メッセージにファイル名を格納
       msg2 = msg2 & file & vbCrLf

      End If
      
     '#次のファイルを格納(※引数なしDirは次のファイルを返す)
      file = Dir
   Loop
     
   '#終了メッセージ表示
   MsgBox msg2
   
   '# 画面更新オン
   Application.ScreenUpdating = True
  
End Sub